(*<*)
theory Lecture9
imports Main LaTeXsugar OptionalSugar
begin
(*>*)

section "Metatheory of Propositional Logic"

text{*

  We formalize the meaning of propositional formulas and
  define a proof system. We prove completeness of the proof system 
  via Kalmar's variable elimination method.
  The material in this section is based on several
  texts on Mathematical Logic~\cite{Bilaniuk:fk,Mendelson:1997lr}
  and Paulson's completeness proof in Isabelle/ZF~\cite{Paulson:1995fk}.

*}


subsection "Formulas and their meaning"

datatype formula
  = Atom nat
  | Neg formula
  | Implies formula formula   (infixl "\<rightarrow>" 101)

consts eval :: "(nat \<Rightarrow> bool) \<Rightarrow> formula \<Rightarrow> bool"
primrec
  "eval v (Atom a) = v a"
  "eval v (Neg \<phi>) = (\<not> (eval v \<phi>))"
  "eval v (\<phi> \<rightarrow> \<psi>) = ((eval v \<phi>) \<longrightarrow> eval v \<psi>)"

constdefs tautology :: "formula \<Rightarrow> bool"
  "tautology \<phi> \<equiv> (\<forall> v. eval v \<phi>)"
  satisfies :: "(nat \<Rightarrow> bool) \<Rightarrow> formula set \<Rightarrow> bool" ("_ sats _" [80,80] 80)
  "v sats \<Sigma> \<equiv> (\<forall> \<phi> \<in> \<Sigma>. eval v \<phi>)"
  satisfiable :: "formula set \<Rightarrow> bool"
  "satisfiable \<Sigma> \<equiv> (\<exists> v. v sats \<Sigma>)"
  implies :: "formula set \<Rightarrow> formula \<Rightarrow> bool" ("_ \<Turnstile> _" [80,80] 80)
  "\<Sigma> \<Turnstile> \<phi> \<equiv> (\<forall> v. v sats \<Sigma> \<longrightarrow> eval v \<phi> = True)"

subsection "Axioms and proofs"

constdefs
  A1 :: "formula"
  "A1 \<equiv> Atom 0 \<rightarrow> (Atom 1 \<rightarrow> Atom 0)"
  A2 :: "formula"
  "A2 \<equiv> (((Atom 0) \<rightarrow> (Atom 1 \<rightarrow> Atom 2)) \<rightarrow>
     (((Atom 0) \<rightarrow> (Atom 1)) \<rightarrow> ((Atom 0) \<rightarrow> (Atom 2))))"
  A3 :: "formula"
  "A3 \<equiv> (((Neg (Atom 1)) \<rightarrow> (Neg (Atom 0)))
         \<rightarrow> (((Neg (Atom 1)) \<rightarrow> Atom 0) \<rightarrow> Atom 1))"
  Axioms :: "formula set"
  "Axioms \<equiv> { A1, A2, A3 }"
declare A1_def[simp] A2_def[simp] A3_def[simp] Axioms_def[simp]

lemma "tautology A1" by (simp add: tautology_def)
lemma "tautology A2" by (simp add: tautology_def)
lemma "tautology A3" by (simp add: tautology_def)

consts subst :: "(nat \<Rightarrow> formula) \<Rightarrow> formula \<Rightarrow> formula"
primrec
  "subst S (Atom x) = (S x)"
  "subst S (Neg f) = Neg (subst S f)"
  "subst S (f1 \<rightarrow> f2) = (subst S f1) \<rightarrow> (subst S f2)"

consts deduction :: "(formula set \<times> formula) set"
syntax deduction :: "formula set \<Rightarrow> formula \<Rightarrow> bool" ("_ \<turnstile> _" [100,100] 100)
translations "\<Sigma> \<turnstile> \<phi>" == "(\<Sigma>,\<phi>) \<in> deduction"
inductive deduction intros
  hyp: "\<lbrakk> \<phi> \<in> \<Sigma> \<rbrakk> \<Longrightarrow> \<Sigma> \<turnstile> \<phi>"
  ax: "\<phi> \<in> Axioms \<Longrightarrow> \<Sigma> \<turnstile> subst S \<phi>"
  mp: "\<lbrakk> \<Sigma> \<turnstile> (\<phi> \<rightarrow> \<psi>); \<Sigma> \<turnstile> \<phi> \<rbrakk> \<Longrightarrow> \<Sigma> \<turnstile> \<psi>"

constdefs emp :: "nat \<Rightarrow> formula"
  "emp \<equiv> (\<lambda> x. (Atom x))"

subsection "Basic properties of the proof system"

lemma aa: "\<Gamma> \<turnstile> (\<phi> \<rightarrow> \<phi>)"
proof -
  let ?S0 = "((emp(0:=\<phi>))(1:=(\<phi>\<rightarrow>\<phi>)))(2:=\<phi>)"
  let ?S1 = "(emp(0:=\<phi>))(1:=(\<phi>))"
  have p1: "\<Gamma> \<turnstile> subst ?S0 A2" apply (rule ax) by simp
  have p2: "\<Gamma> \<turnstile> subst ?S0 A1" apply (rule ax) by simp
  have p3: "\<Gamma> \<turnstile> ((\<phi> \<rightarrow> (\<phi> \<rightarrow> \<phi>)) \<rightarrow> (\<phi> \<rightarrow> \<phi>))"
    using p1 p2 apply simp apply (rule mp) apply blast apply blast done
  have p4: "\<Gamma> \<turnstile> subst ?S1 A1" apply (rule ax) by simp
  show "\<Gamma> \<turnstile> (\<phi> \<rightarrow> \<phi>)"
    using p3 p4 apply simp apply (rule mp) apply blast apply blast done
qed

lemma weakening[rule_format]: "\<Gamma> \<turnstile> \<phi> \<Longrightarrow> (\<forall> \<Delta>. \<Gamma> \<subseteq> \<Delta> \<longrightarrow> \<Delta> \<turnstile> \<phi>)"
  apply (induct rule: deduction.induct)
  apply clarify using hyp apply blast
  using ax apply blast
  apply clarify apply (erule_tac x="\<Delta>" in allE)
    apply (erule_tac x="\<Delta>" in allE) apply clarify
    using mp apply blast done
  
theorem soundness:
  assumes d: "\<Delta> \<turnstile> \<phi>" shows "\<Delta> \<Turnstile> \<phi>"
  using d 
  apply (induct rule: deduction.induct)
  apply (auto simp add: implies_def satisfies_def) 
  done

lemma ppp: assumes A: "\<phi> \<in> \<Gamma>" shows "\<Gamma> \<turnstile> (\<phi>' \<rightarrow> \<phi>)"
proof -
  let ?S = "(emp(0:=\<phi>))(1:=\<phi>')"
  have p1: "\<Gamma> \<turnstile> subst ?S A1" apply (rule ax) by simp
  from A have p2: "\<Gamma> \<turnstile> \<phi>" by (rule hyp)
  from p1 p2 show ?thesis
    apply simp apply (rule mp) apply blast apply simp done
qed
  
lemma deduction_impl:
  "\<Gamma>' \<turnstile> \<psi> \<Longrightarrow> (\<forall> \<phi> \<Gamma>. \<Gamma>' = insert \<phi> \<Gamma> \<longrightarrow> \<Gamma> \<turnstile> (\<phi> \<rightarrow> \<psi>))"
  apply (induct rule: deduction.induct)
  apply clarify apply (case_tac "\<phi>=\<phi>'") apply simp apply (rule aa) 
  apply simp apply (rule ppp) apply simp
  apply clarify
  defer
  apply clarify
  apply (erule_tac x="\<phi>'" in allE)
  apply (erule_tac x="\<Gamma>" in allE)
  apply (erule_tac x="\<phi>'" in allE)
  apply (erule_tac x="\<Gamma>" in allE)
  apply simp
proof -
  fix \<phi> \<psi> \<phi>' \<Gamma>
  assume IH1: "\<Gamma> \<turnstile> (\<phi>' \<rightarrow> (\<phi> \<rightarrow> \<psi>))" and IH2: "\<Gamma> \<turnstile> (\<phi>' \<rightarrow> \<phi>)"
  let ?S = "((emp(0:=\<phi>'))(1:=\<phi>))(2:=\<psi>)"
  have p1: "\<Gamma> \<turnstile> subst ?S A2" apply (rule ax) by simp
  from IH1 p1 have p2: "\<Gamma> \<turnstile> ((\<phi>' \<rightarrow> \<phi>) \<rightarrow> (\<phi>' \<rightarrow> \<psi>))"
    apply simp apply (rule mp) apply blast apply blast done
  from p2 IH2 show "\<Gamma> \<turnstile> (\<phi>' \<rightarrow> \<psi>)" by (rule mp)
next
  fix S \<Sigma> \<phi> \<phi>' \<Gamma>
  assume pa: "\<phi> \<in> Axioms"
  from pa have A: "\<Gamma> \<turnstile> subst S \<phi>" by (rule ax)
  let ?S = "(emp(0:=subst S \<phi>))(1:=\<phi>')"
  have p1: "\<Gamma> \<turnstile> subst ?S A1" apply (rule ax) by simp
  from A p1 show "\<Gamma> \<turnstile> (\<phi>' \<rightarrow> subst S \<phi>)" 
    apply simp apply (rule mp) apply blast apply simp done
qed

theorem deduction:
  "insert \<phi> \<Gamma> \<turnstile> \<psi> \<Longrightarrow> \<Gamma> \<turnstile> (\<phi> \<rightarrow> \<psi>)" using deduction_impl by simp

lemma cut_rule: 
  assumes A: "\<Gamma> \<turnstile> \<phi>" and B: "insert \<phi> \<Gamma> \<turnstile> \<psi>" shows "\<Gamma> \<turnstile> \<psi>"
proof -
  from B have C: "\<Gamma> \<turnstile> (\<phi> \<rightarrow> \<psi>)" by (rule deduction)
  from C A show ?thesis by (rule mp)
qed

lemma mphyp: 
  assumes ppG: "\<phi> \<rightarrow> \<psi> \<in> \<Gamma>" and pG: "\<phi> \<in> \<Gamma>" shows "\<Gamma> \<turnstile> \<psi>"
proof -
  from pG have Gp: "\<Gamma> \<turnstile> \<phi>" by (rule hyp)
  from ppG have pp: "\<Gamma> \<turnstile> (\<phi> \<rightarrow> \<psi>)" by (rule hyp)
  from pp Gp show "\<Gamma> \<turnstile> \<psi>" by (rule mp)
qed

lemma cor_1_10a: "{b\<rightarrow>c,c\<rightarrow>d} \<turnstile> (b\<rightarrow>d)"
proof -
  let ?E = "{b\<rightarrow>c,c\<rightarrow>d}"
  have C: "insert b ?E \<turnstile> c" apply (rule mphyp) apply blast apply  blast done
  have CD: "insert b ?E \<turnstile> c\<rightarrow>d" apply (rule hyp) by blast
  from CD C have "insert b ?E \<turnstile> d" by (rule mp)
  thus "?E \<turnstile> (b\<rightarrow>d)" by (rule deduction)
qed

lemma cor_1_10b: "{b\<rightarrow>(c\<rightarrow>d), c} \<turnstile> (b\<rightarrow>d)"
proof -
  let ?E = "{b\<rightarrow>(c\<rightarrow>d), c}"
  have CD: "insert b ?E \<turnstile> (c\<rightarrow>d)" apply (rule mphyp) apply blast by blast 
  have C: "insert b ?E \<turnstile> c" apply (rule hyp) by simp
  from CD C have "insert b ?E \<turnstile> d" by (rule mp)
  thus ?thesis by (rule deduction)
qed
  
lemma lem_1_11_a: "\<Gamma> \<turnstile> ((Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
proof -
  let ?S = "(emp(0:=Neg \<phi>))(1:=\<phi>)"
  have p1: "\<Gamma> \<turnstile> subst ?S A3" apply (rule ax) by simp
  have p2: "\<Gamma> \<turnstile> (Neg \<phi> \<rightarrow> Neg \<phi>)" by (rule aa)

  have "{subst ?S A3, (Neg \<phi> \<rightarrow> Neg \<phi>)} \<turnstile> ((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
    apply simp by (rule cor_1_10b)
  hence A: "(insert (subst ?S A3) (insert (Neg \<phi> \<rightarrow> Neg \<phi>) \<Gamma>)) \<turnstile> ((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
    using weakening apply blast done
  obtain x where X: "x = (insert (Neg \<phi> \<rightarrow> Neg \<phi>) \<Gamma>)" by simp
  from X A have B: "(insert (subst ?S A3) x) \<turnstile> ((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)" by simp
  from p1 X have p3: "x \<turnstile> subst ?S A3" using weakening apply blast done
  from p3 B have "x \<turnstile> ((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
    by (rule cut_rule)
  with X have C: "insert (Neg \<phi> \<rightarrow> Neg \<phi>) \<Gamma> \<turnstile> ((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)" by simp
  let ?Y = "((Neg \<phi> \<rightarrow> Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
  from p2 C have D: "\<Gamma> \<turnstile> ?Y" by (rule cut_rule)
  let ?S1 = "(emp(0:=Neg (Neg \<phi>)))(1:=Neg \<phi>)"
  have E: "\<Gamma> \<turnstile> subst ?S1 A1" apply (rule ax) by simp
  let ?Z = "((Neg (Neg \<phi>)) \<rightarrow> \<phi>)"
  have F: "{subst ?S1 A1, ?Y} \<turnstile> ?Z" apply simp by (rule cor_1_10a)
  obtain y where Y: "y = (insert ?Y \<Gamma>)" by simp
  from F Y have G: "insert (subst ?S1 A1) y \<turnstile> ?Z" using weakening apply blast done
  from E Y have H: "y \<turnstile> subst ?S1 A1" using weakening apply blast done
  from H G have "y \<turnstile> ?Z" by (rule cut_rule)
  with Y have I: "insert ?Y \<Gamma> \<turnstile> ?Z" by simp
  from D I show "\<Gamma> \<turnstile> ?Z" by (rule cut_rule)
qed
  
lemma lem_1_11_b: "\<Gamma> \<turnstile> (\<phi> \<rightarrow> (Neg (Neg \<phi>)))" 
proof -
  let ?S = "(emp(0:=\<phi>))(1:=(Neg (Neg \<phi>)))"
  have p1: "\<Gamma> \<turnstile> subst ?S A3" apply (rule ax) by simp
  have p2: "\<Gamma> \<turnstile> ((Neg (Neg (Neg \<phi>))) \<rightarrow> (Neg \<phi>))" by (rule lem_1_11_a)
  let ?P3 = "((Neg (Neg (Neg \<phi>))) \<rightarrow> \<phi>) \<rightarrow> Neg (Neg \<phi>)"
  from p1 p2 have p3: "\<Gamma> \<turnstile> ?P3" apply simp apply (rule mp) apply blast apply blast done
  let ?S1 = "(emp(0:=\<phi>))(1:=(Neg (Neg (Neg \<phi>))))"
  let ?P4 = "\<phi>\<rightarrow>(Neg(Neg(Neg \<phi>))\<rightarrow>\<phi>)"
  have "\<Gamma> \<turnstile> subst ?S1 A1" apply (rule ax) by simp
  hence p4: "insert ?P3 \<Gamma> \<turnstile> ?P4" apply simp using weakening by blast
  have "{?P4, ?P3} \<turnstile> \<phi> \<rightarrow> (Neg (Neg \<phi>))" by (rule cor_1_10a)
  hence "(insert ?P4 (insert ?P3 \<Gamma>)) \<turnstile> \<phi> \<rightarrow> (Neg (Neg \<phi>))" using weakening by blast
  with p4 have "(insert ?P3 \<Gamma>) \<turnstile> \<phi> \<rightarrow> (Neg (Neg \<phi>))" using cut_rule by blast
  with p3 show "\<Gamma> \<turnstile> \<phi> \<rightarrow> (Neg (Neg \<phi>))" using cut_rule by blast
qed
lemma lem_1_11_c: "\<Gamma> \<turnstile> (Neg \<phi> \<rightarrow> (\<phi> \<rightarrow> \<psi>))" sorry
lemma lem_1_11_d: "\<Gamma> \<turnstile> ((Neg \<psi> \<rightarrow> Neg \<phi>) \<rightarrow> (\<phi> \<rightarrow> \<psi>))" sorry
lemma lem_1_11_e: "\<Gamma> \<turnstile> ((\<phi> \<rightarrow> \<psi>) \<rightarrow> (Neg \<psi> \<rightarrow> Neg \<phi>))" sorry
lemma lem_1_11_f: "\<Gamma> \<turnstile> (\<phi> \<rightarrow> (Neg \<psi> \<rightarrow> Neg (\<phi> \<rightarrow> \<psi>)))" sorry
lemma lem_1_11_g: "\<Gamma> \<turnstile> ((\<phi> \<rightarrow> \<psi>) \<rightarrow> ((Neg \<phi> \<rightarrow> \<psi>) \<rightarrow> \<psi>))" sorry


subsection "Completeness"


consts hyps :: "nat set \<Rightarrow> formula \<Rightarrow> formula set"
primrec
  "hyps T (Atom n) = (if n \<in> T then {Atom n} else {Neg (Atom n)})"
  "hyps T (Neg \<phi>) = hyps T \<phi>"
  "hyps T (\<phi> \<rightarrow> \<psi>) = hyps T \<phi> \<union> hyps T \<psi>"

lemma hyps_finite: "finite (hyps T \<phi>)"
  apply (induct \<phi>) apply auto done

lemma hyps_member: "\<forall> T x. x \<in> hyps T \<phi> \<longrightarrow> (\<exists> \<alpha>. (x = Atom \<alpha> \<and> \<alpha> \<in> T)
     \<or> (x = Neg (Atom \<alpha>) \<and> \<alpha> \<notin> T))"
  apply (induct \<phi>) by auto

lemma hyps_diff: "hyps (T-{\<alpha>}) \<phi> \<subseteq> insert (Neg (Atom \<alpha>)) ((hyps T \<phi>) - {Atom \<alpha>})"
  apply (induct \<phi>) by auto

lemma hyps_cons:
    "hyps (insert \<alpha> T) \<phi> \<subseteq> insert (Atom \<alpha>) ((hyps T \<phi>)-{Neg (Atom \<alpha>)})"
  by (induct_tac \<phi>) auto

constdefs flip :: "(nat set) \<Rightarrow> formula \<Rightarrow> formula"
  "flip T \<phi> \<equiv> (if eval (\<lambda> x. x \<in> T) \<phi> then \<phi> else Neg \<phi>)"
lemma "eval (\<lambda> x. x \<in> T) (flip T \<phi>)" by (simp add: flip_def)

lemma kalmar[rule_format]:
  "\<forall> \<phi>. size \<phi> = n \<longrightarrow> hyps v \<phi> \<turnstile> flip v \<phi>"
  apply (induct rule: nat_less_induct)
  apply clarify
proof -
  fix n and \<phi>::formula
  assume IH: "\<forall> m<size \<phi>. \<forall> \<phi>. size \<phi> = m \<longrightarrow> hyps v \<phi> \<turnstile> flip v \<phi>"
  show "hyps v \<phi> \<turnstile> flip v \<phi>"
  proof (cases \<phi>)
    fix \<alpha> assume p: "\<phi> = Atom \<alpha>"
    thus ?thesis apply (simp add: flip_def) using hyp by blast
  next
    fix \<psi> assume p: "\<phi> = Neg \<psi>"
    show ?thesis
    proof (cases "eval (\<lambda> x. x \<in> v) \<psi>")
      assume ev: "eval (\<lambda> x. x \<in> v) \<psi>"
      from ev have evnp: "\<not> (eval (\<lambda> x. x \<in> v) (Neg \<psi>))" by simp
      from ev have fp: "flip v \<psi> = \<psi>" by (simp add: flip_def)
      from evnp p have fnp: "flip v \<phi> = Neg \<phi>" by (simp add: flip_def)
      from p have "size \<psi> < size \<phi>" by simp
      with IH have "hyps v \<psi> \<turnstile> flip v \<psi>" by blast
      with fp have A: "hyps v \<psi> \<turnstile> \<psi>" by simp
      have B: "hyps v \<psi> \<turnstile> \<psi> \<rightarrow> (Neg (Neg \<psi>))" by (rule lem_1_11_b)
      from B A have "hyps v \<psi> \<turnstile> Neg (Neg \<psi>)" by (rule mp)
      with fnp p show ?thesis by simp
    next
      assume ev: "\<not> eval (\<lambda> x. x \<in> v) \<psi>"
      from ev p have evp: "eval (\<lambda> x. x \<in> v) \<phi>" by simp
      hence fp: "flip v \<phi> = \<phi>" by (simp add: flip_def)
      from ev have fps: "flip v \<psi> = Neg \<psi>" by (simp add: flip_def)
      from p have "size \<psi> < size \<phi>" by simp
      with IH have "hyps v \<psi> \<turnstile> flip v \<psi>" by blast
      with fps p fp  show ?thesis by simp
    qed
  next
    fix \<psi>1 \<psi>2 assume p: "\<phi> = \<psi>1 \<rightarrow> \<psi>2"
    from p have s1: "size \<psi>1 < size \<phi>" by simp
    from s1 IH have IH1: "hyps v \<psi>1 \<turnstile> flip v \<psi>1" by blast
    from p have s2: "size \<psi>2 < size \<phi>" by simp
    from s2 IH have IH2: "hyps v \<psi>2 \<turnstile> flip v \<psi>2" by blast
    show ?thesis
    proof (cases "eval (\<lambda> x. x \<in> v) \<psi>1")
      assume ev1: "eval (\<lambda> x. x \<in> v) \<psi>1"
      from ev1 have f1: "flip v \<psi>1 = \<psi>1" by (simp add: flip_def)
      show ?thesis
      proof (cases "eval (\<lambda> x. x \<in> v) \<psi>2")
        assume ev2: "eval (\<lambda> x. x \<in> v) \<psi>2"
        from ev2 have f2: "flip v \<psi>2 = \<psi>2" by (simp add: flip_def)
        from p ev2 have fp: "flip v \<phi> = \<phi>" by (simp add: flip_def)
        from f2 IH2 have ps2: "hyps v \<psi>2 \<turnstile> \<psi>2" by simp
        let ?S = "(emp(0:=\<psi>2))(1:=\<psi>1)"
        have "hyps v \<psi>2 \<turnstile> subst ?S A1" apply (rule ax) by simp
        with ps2 p have X: "hyps v \<psi>2 \<turnstile> \<phi>" 
	  apply simp apply (rule mp) 
          apply blast apply blast done
	from p have "hyps v \<psi>2 \<subseteq> hyps v \<phi>"
	  apply simp by blast
        with X have "hyps v \<phi> \<turnstile> \<phi>" by (rule weakening)
	with fp show ?thesis by simp
      next
	assume ev2: "\<not> eval (\<lambda> x. x \<in> v) \<psi>2"
	hence fp2: "flip v \<psi>2 = Neg \<psi>2" by (simp add: flip_def)
	from p ev2 have "\<not> eval (\<lambda> x. x \<in> v) \<phi>" by simp
	hence fp: "flip v \<phi> = Neg \<phi>" by (simp add: flip_def)

	from p have p1p: "hyps v \<psi>1 \<subseteq> hyps v \<phi>" 
	  apply simp by blast
	from IH1 f1 have p1p1: "hyps v \<psi>1 \<turnstile> \<psi>1" by simp
	from p1p1 p1p have p1: "hyps v \<phi> \<turnstile> \<psi>1" by (rule weakening)

	from p have p2p: "hyps v \<psi>2 \<subseteq> hyps v \<phi>" 
	  apply simp by blast
	from IH2 fp2 have p2p2: "hyps v \<psi>2 \<turnstile> Neg \<psi>2" by simp
	from p2p2 p2p have p2: "hyps v \<phi> \<turnstile> Neg \<psi>2" by (rule weakening)
	
	have "hyps v \<phi> \<turnstile> (\<psi>1 \<rightarrow> (Neg \<psi>2 \<rightarrow> Neg (\<psi>1 \<rightarrow> \<psi>2)))" 
	  by (rule lem_1_11_f)
	with p1 have "hyps v \<phi> \<turnstile> Neg \<psi>2 \<rightarrow> Neg (\<psi>1 \<rightarrow> \<psi>2)" 
	  using mp by blast
	with p2 have "hyps v \<phi> \<turnstile> Neg (\<psi>1 \<rightarrow> \<psi>2)"  
	  using mp by blast
	with fp p show ?thesis by simp
      qed
    next
      assume ev1: "\<not> eval (\<lambda> x. x \<in> v) \<psi>1"
      with p have ep: "eval (\<lambda> x. x \<in> v) \<phi>" by simp
      from ev1 have f1: "flip v \<psi>1 = Neg \<psi>1" by (simp add: flip_def)
      from ep have fp: "flip v \<phi> = \<phi>" by (simp add: flip_def)
      from f1 IH1 have ps1: "hyps v \<psi>1 \<turnstile> Neg \<psi>1" by simp
      have p12: "hyps v \<psi>1 \<turnstile> (Neg \<psi>1 \<rightarrow> (\<psi>1 \<rightarrow> \<psi>2))" by (rule lem_1_11_c)
      from p12 ps1 have "hyps v \<psi>1 \<turnstile> \<psi>1 \<rightarrow> \<psi>2" by (rule mp)
      with p have X: "hyps v \<psi>1 \<turnstile> \<phi>" by simp
      from p have Y: "hyps v \<psi>1 \<subseteq> hyps v \<phi>"
        apply simp by blast
      from Y X fp show ?thesis apply simp apply (rule weakening) apply blast by blast
    qed
  qed
qed

lemma excluded_middle:
  assumes pp: "insert \<phi> \<Gamma> \<turnstile> \<psi>" and npp: "insert (Neg \<phi>) \<Gamma> \<turnstile> \<psi>"
  shows "\<Gamma> \<turnstile> \<psi>"
proof -
  from pp have a: "\<Gamma> \<turnstile> \<phi> \<rightarrow> \<psi>"  by (rule deduction)
  from npp have b: "\<Gamma> \<turnstile> Neg \<phi> \<rightarrow> \<psi>"  by (rule deduction)
  have c: "\<Gamma> \<turnstile> (\<phi>\<rightarrow>\<psi>) \<rightarrow> ((Neg \<phi> \<rightarrow> \<psi>) \<rightarrow> \<psi>)" by (rule lem_1_11_g)
  from c a have d: "\<Gamma> \<turnstile> ((Neg \<phi> \<rightarrow> \<psi>) \<rightarrow> \<psi>)" by (rule mp)
  from d b show "\<Gamma> \<turnstile> \<psi>" by (rule mp)
qed

lemma variable_elimination:
  "finite H \<Longrightarrow> (\<forall> \<phi>. tautology \<phi> \<and> H \<subseteq> hyps T0 \<phi> \<longrightarrow>
     (\<forall> T.  (hyps T \<phi> - H) \<turnstile> \<phi>))"
  apply (induct rule: finite_induct) apply clarify defer apply clarify defer
proof -
  fix \<phi> T assume taut: "tautology \<phi>" 
  have "hyps T \<phi> \<turnstile> flip T \<phi>" apply (rule kalmar) by simp
  with taut show "(hyps T \<phi> - {}) \<turnstile> \<phi>" by (simp add: flip_def tautology_def)
next
  fix x H \<phi> T
  assume IH: "\<forall>\<phi>. tautology \<phi> \<and> H \<subseteq> hyps T0 \<phi> \<longrightarrow> (\<forall> T. (hyps T \<phi> - H) \<turnstile> \<phi>)"
    and taut: "tautology \<phi>" and xfh: "insert x H \<subseteq> hyps T0 \<phi>"
  from xfh obtain \<alpha> where X: "(x = Atom \<alpha> \<and> \<alpha> \<in> T0)
    \<or> (x = Neg (Atom \<alpha>) \<and> \<alpha> \<notin> T0)" using hyps_member by blast
  moreover { assume X: "x = Atom \<alpha> \<and> \<alpha> \<in> T0"
    have "(hyps T \<phi> - insert (Atom \<alpha>) H) \<turnstile> \<phi>"
    proof (rule excluded_middle[of "Atom \<alpha>"])
      from taut xfh IH have a: "(hyps T \<phi> - H) \<turnstile> \<phi>" by blast
      have b: "hyps T \<phi> - H \<subseteq> insert (Atom \<alpha>) (hyps T \<phi> - insert (Atom \<alpha>) H)" by blast
      from a b show "insert (Atom \<alpha>) (hyps T \<phi> - insert (Atom \<alpha>) H) \<turnstile> \<phi>" using weakening by blast
    next
      from taut xfh IH have a: "(hyps (T-{\<alpha>}) \<phi> - H) \<turnstile> \<phi>" by blast
      have "hyps (T-{\<alpha>}) \<phi> \<subseteq> insert (Neg (Atom \<alpha>)) ((hyps T \<phi>) - {Atom \<alpha>})"
        by (rule hyps_diff)
      with X have b: "(hyps (T-{\<alpha>}) \<phi>) - H \<subseteq> insert (Neg (Atom \<alpha>)) (hyps T \<phi> - insert (Atom \<alpha>) H)" 
        by blast
      from a b show "insert (Neg (Atom \<alpha>)) (hyps T \<phi> - insert (Atom \<alpha>) H) \<turnstile> \<phi>" 
        using weakening by blast
    qed
  } moreover { assume X: "x = Neg (Atom \<alpha>) \<and> \<alpha> \<notin> T0"
    have "(hyps T \<phi> - insert (Neg (Atom \<alpha>)) H) \<turnstile> \<phi>"
    proof (rule excluded_middle[of "Atom \<alpha>"])
      from taut xfh IH have a: "(hyps (insert \<alpha> T) \<phi> - H) \<turnstile> \<phi>" by blast
      have b: "hyps (insert \<alpha> T) \<phi> \<subseteq> insert (Atom \<alpha>) (hyps T \<phi> - {Neg (Atom \<alpha>)})" by (rule hyps_cons)
      from b have c: "hyps (insert \<alpha> T) \<phi> - H
                      \<subseteq> insert (Atom \<alpha>) (hyps T \<phi> - insert (Neg (Atom \<alpha>)) H)" by blast
      from a c show "insert (Atom \<alpha>) (hyps T \<phi> - insert (Neg (Atom \<alpha>)) H) \<turnstile> \<phi>" 
        using weakening by blast 
    next
      from taut xfh IH have a: "(hyps T \<phi> - H) \<turnstile> \<phi>" by blast
      have b: "hyps T \<phi> - H \<subseteq> insert (Neg (Atom \<alpha>)) (hyps T \<phi> - insert (Neg (Atom \<alpha>)) H)" by blast
      from a b show "insert (Neg (Atom \<alpha>)) (hyps T \<phi> - (insert (Neg (Atom \<alpha>)) H)) \<turnstile> \<phi>" 
        using weakening by blast
    qed
  } ultimately show "(hyps T \<phi> - insert x H) \<turnstile> \<phi>" by blast
qed

theorem completeness:
  assumes taut: "tautology \<phi>" shows "{} \<turnstile> \<phi>"
proof -
  have "finite (hyps T \<phi>)" by (rule hyps_finite)
  with taut have "(hyps T \<phi> - hyps T \<phi>) \<turnstile> \<phi>" using variable_elimination by blast
  thus ?thesis by simp
qed

(*<*)
end
(*>*)